# $FreeBSD: src/etc/root/dot.login,v 1.22 2000/07/15 03:25:14 rwatson Exp $
#
# .login - csh login script, read by login shell, after `.cshrc' at login.
#
# see also csh(1), environ(7).
#
set path = (/sbin /bin /usr/sbin /usr/bin /opt/sbin /opt/bin /usr/local/bin )
umask 22

# default to glass tty/erase=^H if the following tset fails
stty crt erase ^h

# set TERM variable and terminal type.  Ask for dialup/unknown/network
eval "`tset -Q -s -m 'dialup:?vt100' -m 'unknown:?vt100' -m 'network:?xterm'`"

# don't set TERMCAP, it gets in the way of resizing the screen at times
unsetenv TERMCAP

# Showing banner only if running OS is JSR version and factory default
set DEFOS = `uname -v | awk -F/ '{ print $NF }'`

if (-f "/config/juniper.conf.gz") then
set DEFCONF = `zcat /config/juniper.conf.gz | grep -c root-authentication`
else
  if (-f "/config/juniper.conf") then
  set DEFCONF = `grep -c root-authentication /config/juniper.conf`
  else
  set DEFCONF = 1 # set to non-zero value
  endif
endif

if (!($DEFCONF) && -f "/etc/banner.$DEFOS") then
    cat "/etc/banner.$DEFOS"
endif

